精华区文章阅读

发信人: mengy (LEAR DLLS 命令时，将从内存中清除), 信区: Database
标  题: Visual Foxpro 与ASP 相结合开发Web 数据库应
发信站: 哈工大紫丁香 (2000年12月13日07:59:44 星期三), 站内信件

　

　

Visual Foxpro 与ASP 相结合开发Web 数据库应用
重庆出版社电脑中心陈刚
1 ． VFP 与Web 数据库应用 ---- 作为最成功的大众数据库，
Foxpro 简便易学，有广大的用户。随着VFP 5.0 的推出，VFP 已
经成为一个强大的企业级开发工具。它不仅可以开发文
件/ 服务器（F/S）数据库应用，也可以开发C/S 应用，这时
VFP 作为一个前端工具，后端可以是SQL Server，Sybase 等数据
库Engine。通过Remote View 和SQL Passthrough 函数，VFP 可以像操作
本地数据一样，方便地处理服务器端数据。
---- 在Internet/ Intranet 影响日益巨大的今天，开发Web 数据库
应用成为引人关注的技术。Web 数据库应用有一个天然的
多层C/S 结构。在这个结构中，客户端（Client）仅由Browser 组
成，几乎没有软件维护和升级的问题。来自Client 的请求
发送到Web Server，我们只须开发Web Server 端软件，处理请求
，与数据库服务器交互、并把结果返回Client，系统维护和
升级非常方便。只要允许，任意一个客户都可以通过
Internet 或Intranet 访问我们的数据。

---- VFP 完全具备开发Web 数据库应用的能力。不过有意思
的是，这次VFP 被推到了后台，在数据库服务器上专门处理
数据存取和实现商业逻辑。数据库服务器和Web Server 可以
运行在同一个网络服务器上，或者运行在由高速通道连
接的两台网络服务器上（如NT Server），这样网络传输瓶颈
不再存在。并且借助NT Server 的安全管理，客户并不能直
接接触VFP 数据库，而是通过Web Server 存取数据，VFP 数据库
的安全特性得以大大提高，而此两项一般认为是VFP 的重
要弱点。

2 ． ASP（Active Server Page）与 VFP 的组件技术 ---- Web 数据库
应用可以由CGI、ISAPI、IDC、ASP 等实现。其中ASP 的功能最为强
大，在其中可以混用HTML、DHTML、ActiveX、VBSsript 或JavaSript，
特别是可以使用服务器端组件。此服务器端组件可以用
VFP、VB、VC++、Delphi 等任意支持COM 技术的语言编写，以实现
用户特定的商业逻辑。如果不出意外，ASP 将成为主流技
术。目前有Microsoft 的IIS（Internet Information Server，NT Server）
和PWS（Personel Web Server，Win95）支持ASP。
---- 在传统的F/S 或C/S 应用中，组件作为面向对象的编程风
格，你可以随自己的喜好，采用或不采用它。然而在ASP 中
使用VFP，组件（一个OLE Server DLL）是你唯一的选择。你的
处理过程都应封装在一个或多个组件中。

3 ．使用的环境和工具 ---- 对于ASP ，需要WinNT 4.0（Service
Pack 3）、IIS 3.0（WinNT 自带）、Visual InterDev1.0 。也可以是：
Win95、PWS(Visual InterDev1.0 中提供) 、Visual InterDev1.0。
---- 为了使IIS 或 PWS 支持ASP，在安装Visual InterDev 时必须首
先在服务器上选择安装其中的Server Components：FrontPage
Server Extensions 和 Active Server Pages，然后在开发服务器上安
装Client Components：Visual InterDev Client。也可以把这些都安
装在同一台机器上，这样可以在单机上方便地编程、调试
。

4. VFP 组件的实现 ---- 在VFP 中开始一个Project，取名为
Classes，然后在此Project 中建立一个Program，取名Classdef.prg。
它定义了一个OneRecord 类，其功能是一条条显示一个数据
库，具有向前、向后和定位能力。使用一个DBF 文件d:
\vfpweb\data\booksno.dbf，结构为：
Field_name Field_type Field_len
bookno  C   16
bookname C    50
author  C    12
editor  C   14
pubdate  D   8
charnum   N   4.0

在Classdef.prg 中键入代码：
Define class onerecord as custom olepublic
mcDatapath=""
*---------------------------
function getdatapath
return (this.mcdatapath)
*---------------------------
function getcurrentno
return recno()
*---------------------------
function init
set exclu off
set century on
set date to ansi
return
*---------------------------
function  setdatapath
lparameter cpath
if type("cpath")<  >"C"
return
endif
this.mcdatapath=cpath
set defau to (cpath)
if not used("booksno")
select 0
use booksno
else
select booksno
endif
return
*--------------------------
function movenext
if .not.eof()
skip
endif
return
*--------------------------
function moveprevious
if .not.bof()
skip -1
endif
return
*--------------------------
function destroy
use
*clear all &&clear all 将挂起服务器
return
*--------------------------
function iseof
if eof()
return .t.
else
return .f.
endif
*--------------------------
function  isbof
if bof()
return .t.
else
return .f.
endif
*--------------------------
function getbookno
return bookno
*--------------------------
function getpubdate
if empty(pubdate)
return ""
else
return pubdate
endif
*--------------------------
function geteditor
return editor
*--------------------------
function getbookname
return bookname
*--------------------------
function goto
lparameter recnum
if type("recnum")<  >"N"  &&error data type

return
endif
if recnum< 1 .or. recnum >reccount()
return
else
goto (recnum)
endif
return
EndDefine
---- 在菜单Project，选中 Set Main，然后Build ，在Build 对话框
中选Build OLE DLL。好了，我们到此就完成了一个OLE Server，
并且它已经自动注册在我们的机器上。我们可以在菜单
Project | Project Info 弹出的Project Information 对话框中看到这
个组件的信息：

Server Classes：onerecord
Project Name：Classes
OLE
---- Server 的引用方法是createobject("ProjectName.ClassName"), 对
于我们这个组件, 就是：createobject("classes.onerecord")。可以
直接在VFP 的Command 窗口中交互式地测试之，在Command 窗口中
键入：

ox=createobject("classes.onerecord")
ox.setdatapath("d:\vfpweb\data")
?ox.bookname
?ox.getbookname
ox.movenext
?ox.getbookname
ox.goto(30)
?ox.getbookname
---- 可以直接看到执行结果，最后不要忘了释放该组件：

release ox
---- 这个组件是针对特定数据库进行操作的，测试很方便
。下面，我们再实现一个更为一般的类ClsQ2T，其功能是任
意指定一条SQL 查询语句（针对任意一个或多个数据库），
将查询结果以表格的形式显示在Web 页面上，其中使用了
ASP 的接口。它不仅封装了数据处理，而且通过ASP 接口，也
封装了数据显示。

---- 仍在Classdef.prg 之中，接着最后一行代码，键入：

***************************************************
define class clsq2t as custom olepublic
mcontext=.null.
*-----------------------------------------
function onstartpage(ocontext)
this.mcontext=ocontext &&对ASP接口的引用
return
*-----------------------------------------
function init
set exclu off
set safety off
return
*---------------------------------------------
function setdatapath(strpath)
merrnum=0
on error merrnum=error( )
set default to (strpath)
if merrnum<  >0
return "Error in setdatapath"+message()+chr(13)
endif
on error
return "OK,setdatapath"+strpath+chr(13)
*-------------------------------------------------
*函数querytotable要求传入一个SQL Select串，如：
* "select bookname,editor from booksno where charnum >500"
* -------------------------------------------------
function querytotable(querystring)
merrnum=0
on error merrnum=error( )
oResp=this.mcontext.response &&引用ASP对象response
tempname=SUBSTR(SYS(2015), 3, 10) &&产生唯一的文件名
&querystring into cursor (tempname)
if merrnum<  >0
return "Error in querytotable,create sql view"+message()
       +alltrim(str(lineno( )))+chr(13)
endif
outstring="< table border=1 >"+chr(13)+"< tr >"+chr(13)
oresp.write(outstring)
if merrnum<  >0
return "Error in querytotable,oresp.write"+message()
         +alltrim(str(lineno( )))+chr(13)
endif
outstring=""
fc=fcount()
for i=1 to fc
if type("eval(field(i))")="G"
  loop
endif
outstring=outstring+"< td >"+field(i)+"< /td >"+chr(13)
next
outstring=outstring+"< /tr >"+chr(13)
oresp.write(outstring)
outstring=""
if merrnum<  >0
return "error in oresp.write header"+message()
      +alltrim(str(lineno( )))+chr(13)
endif
scan
outstring=outstring+"< tr >"+chr(13)
for i=1 to fc
  if type("eval(field(i))")="G"
   loop
  endif
  mt=eval(field(i))
  do case
   case type("mt")="C"
    outstring=outstring+"< td >"+mt+"< /td >"
   case type("mt")="T"
    outstring=outstring+"< td >"+ttoc(mt)+"< /td >"
   case type("mt")="D"
    outstring=outstring+"< td >"+dtoc(mt)+"< /td >"
   case type("mt")$"NY"
    outstring=outstring+"< td >"+alltrim(str(mt,5))+"< /td >"
  endcase
  outstrin=outstring+chr(13)
next
outstring=outstring+"< /tr >"+chr(13)
endscan
oresp.write(outstring)
outstring="< /table >"
oresp.write(outstring)
use
on error
return "OK of querytotable, ended"+chr(13)
endfunc
EndDefine
---- 键入代码后Build ，在Build 对话框中仍选Build OLE DLL，在
确认覆盖时选择"Y"，在Project Information 对话框中看到这个
组件的信息已有变化：

Server Classes：onerecord clsq2t
Project Name：Classes
---- 加上了新增的clsq2t。

---- 这段代码中较特别的是onstartpage(ocontext)，它在每次.
asp 页面启动时由IIS 自动调用，并传入一个参数。该参数
是对ASP 的一个容器ScriptingContext 的引用，通过它可以引用
ASP 的所有内在对象（Intrinsic Object），如response、reuqest。通
过这些内在对象，VFP 可以直接读取用户在Web 页面上的输
入，也可以把结果直接写回Web 页面。

---- 组件clsq2t 的调试要困难得多。可以在函数querytotable 中
注释掉与oResp 有关的行以及define class clsq2t as custom
olepublic 和 EndDefine 两行，然后增加一些代码直接调用各个
函数，以进行调试排错。确认无误后再恢复上述各行，并
重新 Build。

5. 在ASP 中使用VFP 组件 ---- 下面将建立两个ASP 页面：
Onerecord.asp 和Clsq2t.asp 测试我们完成的这两个组件。启动
Visual InterDev，开始一个新的工程：New Projects，然后选取Web
Project Wizard ，在Project Name 中输入VFPClasses，点击OK 后，
Visual InterDev 产生一些辅助文件，为新的工程做好准备，
然后打开该工程。我们在该工程中首先建立一个HTML 页面
index.htm，以调用上述两个ASP 页面。点击菜单File | New，在
New 对话框中选Files | HTML Page，并指定HTML 页面的名字：
index.htm。Visual InterDev 将会为我们产生一个空的框架，在
其中用手工加入代码，也可用Visual InterDev 附带的FrontPage
Editor 等可视化工具编辑代码，完成后的HTML 页面如下：
< HTML >
< HEAD >
< /HEAD >
< BODY >
< p >< a href="Onerecord.asp" >To scan the records< /a >
        < /p >
< p >To send a query:< br >
< form action="Clsq2t.asp" method="post" name="input" >
< input type="submit" name="Btoquery" value="Query" >
< input   type="text" size="40" name="qstring"
           value="Input a query here" >
< /p >
< /form >
< /BODY >
< /HTML >
---- index.htm 中包括一个到Onerecord.asp 的超联接、一个Text 用
于输入查询语句、一个Submit Button 用于提交查询，点击该
Button 后将调用Clsq2t.asp。

---- 点击菜单File | New ，在New 对话框中选Files | Active
Server Page, 新建Onerecord.asp，它使用onerecord 组件在Web 页面上
浏览数据库，代码如下：

< %@ LANGUAGE="VBSCRIPT" % >
< html >
< HEAD >
< /HEAD >
< BODY >
< FORM ACTION="Onerecord.asp" METHOD="POST" ID="scanform" >
< %set ox=server.createobject("classes.onerecord")
ox.setdatapath("d:\vfpweb\data")
if session("currentno")="" then
session("currentno")=1'first time open the page
currentno=1
else
if isnumeric(session("currentno")) then
  currentno=session("currentno")
else
  currentno=1
end if
end if
ox.goto(currentno)
% >
< %if request.form("cmdnext")<  >"" then
ox.movenext
end if% >
< %if request.form("cmdprev")<  >"" then
ox.moveprevious
end if% >
< %if isnumeric(request.form("txtgoto")) then
temp=cint(request.form("txtgoto"))
ox.goto(temp)
end if% >
< %session("currentno")=ox.getcurrentno% >
< p >
当前记录:< %=ox.getcurrentno% >< br >
书  号:< %=ox.getbookno% >< br >
书  名:< %=ox.getbookname% >< br >
责  编:< %=ox.geteditor% >< br >
出版时间:< %=ox.getpubdate% >< br >
< /p >
< p >
< %if not ox.iseof then'如果不是文件未则显示按钮Next% >
< INPUT TYPE=submit VALUE="Next" NAME="cmdnext" >
< %end if% >
< %if not ox.isbof then'如果不是文件头则显示按钮Prev% >
< INPUT TYPE=submit VALUE="Prev" NAME="cmdprev" >
< %end if% >
< %set ox=nothing% >
< INPUT LANGUAGE="VBScript" TYPE=submit
           VALUE="Goto"
ONCLICK="if not isnumeric(scanform.txtgoto.value) then
window.alert("Must input a number")
window.event.cancelbubble=true
end if"
NAME="cmdgoto" >
< INPUT TYPE=text SIZE=20 NAME="txtgoto" >< /p >
< a href=index.htm > Return Index< /a >
< /FORM >
< /BODY >
< /HTML >
---- 该页面显示数据库当前记录各字段的值，并在页面下
方显示三个按钮Next（下一条），Prev（上一条）和Goto。其中
使用了Server Side Code（符号< % 和% > 之间的代码，在服务器
端执行），产生组件及对组件各方法和属性的调用；Client
Side Code（在客户端执行），在ONCLICK 的事件响应中检验用
户输入的记录号（必须是一个数字）。由于Web Browser 基于
的HTTP 是一个无状态协议，它并不知道各客户的当前记录
。为了在各个页面调用中记住当前记录号，使用了
session 对象。session 对象在跟踪和保持客户的使用状态上
很有用处，感兴趣者可以查阅Visual InterDev 的联机帮助。

---- 再新建Clsq2t.asp ，它使用使用clsq2t 组件在Web 页面上显
示任意查寻结果，代码如下：

< %@ LANGUAGE="VBSCRIPT" % >
< HTML >
< HEAD >
< /HEAD >
< BODY >
< %qs=request.form("qstring")% >
你输入的查询要求是: < br >< %=qs% >< hr >
< a href=index.htm > Return Index< /a >< br >
< %set ox=Server.CreateObject("classes.clsq2t")% >
< %ox.SetDataPath("d:\vfpweb\data")% >
< %ox.QueryToTable(qs)% >
< %Set ox = Nothing% >
< /BODY >
< /HTML >
---- 由于输出操作都已封装在组件clsq2t 之中，故该组件的
使用相当简明。应该指出的是，该组件应该用于开发之
中，而不应提供给最终用户，因为不能保证用户输入的SQL
Select 串的有效和合法。

6. 调试注意事项 ---- 此处两个组件皆是进程内服务器，当
有Bug 时将会使系统挂起甚至崩溃。
---- 当修改组件代码时，你会发现无法覆盖老的.dll 文件。
这是因为即使退出Visual InterDev，组件仍被Web Server 锁定（
这就是为什么VFP 试图用clear all 释放资源时会挂起服务器
）。这时必须停止Web Server 并再启动之，在开发过程中可
能要如此反复多次。如果系统被挂起或崩溃，Web Server 无
法响应，这时只有使出最后一招：关机并重新启动。VFP 5.0
版本的Run Time Library 只支持一个实例，就是说：如果上述
两个组件在两个不同的prg 文件中实现，则它们不能同时
被使用。这一点在VFP6.0 中已得到改进（但仍是单线程的）
。

7. 评述 ---- Web 数据库开发更专业化的方法似乎是
ASP+VB+ADO(ActiveX Data Object)+SQLServer。其中ADO 不仅可用于Web
数据库开发，也可用在VB、VFP 中替代DAO、RDO 开发传统的C/S
应用，功能更为强大。然而对于中小企业来说，VFP 简便易
用，对资源要求不高，而且我国很多高校学生都学习过
Foxbase 或Foxpro，他们可以很快掌握Visual Foxpro，故可以比较
容易地找到编程和系统维护人才。VFP 用于开发
Internet/Intranet 是一个较好的选择，国外已有许多大型应
用的成功凡例。

--

       大海无边天做岸
               山登绝顶我为风

※ 来源:·哈工大紫丁香 bbs.hit.edu.cn·[FROM: 202.118.227.121]

Database 版 (精华区)