精华区文章阅读

发信人: zhangyan (今朝有水今朝灌), 信区: Programming
标  题: Iczelion Win32汇编教程(14)
发信站: 哈工大紫丁香 (2001年02月14日16:19:19 星期三), 站内信件

第十四课进程
----------------------------------------------------------------------------
----
本课中我们将学习：什么是进程？如何产生和终止一个进程？
初步知识：
进程是什么？下面是我从WIN32 API指南中节选的解释：
“一个进程是一个正在执行的应用程序，它包含有：私有的虚拟地址空间、代码、数据
和其它的操作系统资源，譬如进程可以存取的管道、文件和同步对象等等。”
从上面的定义中您可以看到，一个进程拥有几个对象：地址空间、执行模块和其它该执
行程序打开或创建的任何对象或资源。至少，一个进程必须包含可执行模块、私有的地
址空间和一个以上的线程。什么是线程呢？一个线程实际上是一个执行单元。当WINDOW
S产生一个进程时，它自动为该进程产生一个主线程。该线程通常从模块的第一条指令处
开始执行。如果进程需要更多的线程，它可以随后显式地产生。
当WINDWOS 接收到产生进程的消息时，它会为进程生成私有内存地址空间，接着把可执
行文件映射到该空间。在WIN32下为进程产生了主进程后，您还可以调用函数CreatePro
cess来为您的进程产生更多的线程。
CreateProcess的原型如下：
CreateProcess proto lpApplicationName:DWORD,\
                                lpCommandLine:DWORD,\
                                lpProcessAttributes:DWORD,\
                                lpThreadAttributes:DWORD,\
                                bInheritHandles:DWORD,\
                                dwCreationFlags:DWORD,\
                                lpEnvironment:DWORD,\
                                lpCurrentDirectory:DWORD,\
                                lpStartupInfo:DWORD,\
                                lpProcessInformation:DWORD
不要被这么多的参数吓倒，其实您可以忽略其中的大多数的参数（让它们有缺省值）。

lpApplicationName --> 可执行文件的名称（含或不含路径）。如果该参数为NULL，那
必须在参数lpCommandLine中传递文件名称。
lpCommandLine --> 传递给欲执行的文件的命令行参数。如果lpApplicationName为NUL
L，那必须在该参数中指定，譬如："notepad.exe readme.txt" 。
lpProcessAttributes 和 lpthreadAttributes --> 指定进程和主线程的安全属性。您
可以把它们都设成为NULL，这样就设置了缺省的安全属性。
bInheritHandles --> 标志位。用来设置新进程是否继承创建进程所有的打开句柄。
dwCreationFlags --> 有几个标志可以在此处设置以决定欲创建进程的行为，譬如：您
可能想创建进程后并不想让它立刻运行，这样在它真正运行前可以作一些检查和修改工
作。您还可以在此处设置新进程中的所有线程的优先级，通常我们把它设置为NORMAL_P
RIORITY_CLASS。
lpEnvironment --> 指向环境块的指针，一般地环境块包含几个环境字符串。如果该参
数为NULL，那么新进程继承创建进程的环境块。
lpCurrentDirectory --> 指向当前目录以及为子进程设置的“当前目录”的路径。如果
为NULL，则继承创建进程的“当前目录”路径。
lpStartupInfo --> 指向新进程的启动结构体STARTUPINFO的指针。STARTUPINFO告诉WI
NDOWS如何显示新进程的外观。该参数有许多的成员变量，如果您不想新进程有什么的特
别之处，可以调用GetStartupInfo函数来用创建进程的启动参数来填充STARTUPINFO结构
体变量。
lpProcessInformation --> 指向结构体PROCESS_INFORMATION的指针，该结构体变量包
含了一些标识该进程唯一性的一些成员变量：
PROCESS_INFORMATION STRUCT
   hProcess          HANDLE ?             ; handle to the child process
   hThread            HANDLE ?             ; handle to the primary thread of
the child process
   dwProcessId     DWORD ?             ; ID of the child process
   dwThreadId      DWORD ?            ; ID of the primary thread of the chil
d process
PROCESS_INFORMATION ENDS
进程句柄和进程ID是两个不同的概念。进程ID好似一个唯一值，而进程句柄是调用相关
的WINDOWS API 后得到的一个返回值。不能用进程句柄来标识一个进程的唯一性，因为
这个值并不唯一。在调用CreateProcess产生新进程后，该进程就被创建，而且CerateP
rocess函数立即返回。您可以调用函数GetExitCodeProcess来检验进程是否结束。该函
数的原型如下：
GetExitCodeProcess proto hProcess:DWORD, lpExitCode:DWORD
如果调用成功，lpExitCode中包含了所查询进程的状态码。如果等于STILL_ACTIVE就表
明该进程依旧存在。您可以调用函数TerminateProcess来强制终止一个进程。该函数的
原型如下：
TerminateProcess proto hProcess:DWORD, uExitCode:DWORD
您可以指定任意一个退出值。用该函数结束一个进程并不好，因为该进程加载的动态连
接库并不会得到进程正退出的消息。
例子：
在下面的例子中，当用户选择菜单项“crate process”时我们创建一个新进程。它会去
执行“"msgbox.exe”。如果用户想要终止新进程，可以选择菜单项“terminate proce
ss”。这时，应用程序检查欲终止的进程是否仍存在，若存在则调用TerminateProcess
函数来终止它。
.386
.model flat,stdcall
option casemap:none
WinMain proto :DWORD,:DWORD,:DWORD,:DWORD
include \masm32\include\windows.inc
include \masm32\include\user32.inc
include \masm32\include\kernel32.inc
includelib \masm32\lib\user32.lib
includelib \masm32\lib\kernel32.lib
.const
IDM_CREATE_PROCESS equ 1
IDM_TERMINATE equ 2
IDM_EXIT equ 3
.data
ClassName db "Win32ASMProcessClass",0
AppName  db "Win32 ASM Process Example",0
MenuName db "FirstMenu",0
processInfo PROCESS_INFORMATION <>
programname db "msgbox.exe",0
.data?
hInstance HINSTANCE ?
CommandLine LPSTR ?
hMenu HANDLE ?
ExitCode DWORD ?                    ; contains the process exitcode status f
rom GetExitCodeProcess call.
.code
start:
       invoke GetModuleHandle, NULL
       mov    hInstance,eax
       invoke GetCommandLine
       mov CommandLine,eax
       invoke WinMain, hInstance,NULL,CommandLine, SW_SHOWDEFAULT
       invoke ExitProcess,eax
WinMain proc hInst:HINSTANCE,hPrevInst:HINSTANCE,CmdLine:LPSTR,CmdShow:DWORD

   LOCAL wc:WNDCLASSEX
   LOCAL msg:MSG
   LOCAL hwnd:HWND
   mov   wc.cbSize,SIZEOF WNDCLASSEX
   mov   wc.style, CS_HREDRAW or CS_VREDRAW
   mov   wc.lpfnWndProc, OFFSET WndProc
   mov   wc.cbClsExtra,NULL
   mov   wc.cbWndExtra,NULL
   push  hInst
   pop   wc.hInstance
   mov   wc.hbrBackground,COLOR_WINDOW+1
   mov   wc.lpszMenuName,OFFSET MenuName
   mov   wc.lpszClassName,OFFSET ClassName
   invoke LoadIcon,NULL,IDI_APPLICATION
   mov   wc.hIcon,eax
   mov   wc.hIconSm,eax
   invoke LoadCursor,NULL,IDC_ARROW
   mov   wc.hCursor,eax
   invoke RegisterClassEx, addr wc
   invoke CreateWindowEx,WS_EX_CLIENTEDGE,ADDR ClassName,ADDR AppName,\
          WS_OVERLAPPEDWINDOW,CW_USEDEFAULT,\
          CW_USEDEFAULT,300,200,NULL,NULL,\
          hInst,NULL
   mov   hwnd,eax
   invoke ShowWindow, hwnd,SW_SHOWNORMAL
   invoke UpdateWindow, hwnd
   invoke GetMenu,hwnd
   mov  hMenu,eax
   .WHILE TRUE
               invoke GetMessage, ADDR msg,NULL,0,0
               .BREAK .IF (!eax)
               invoke TranslateMessage, ADDR msg
               invoke DispatchMessage, ADDR msg
   .ENDW
   mov     eax,msg.wParam
   ret
WinMain endp
WndProc proc hWnd:HWND, uMsg:UINT, wParam:WPARAM, lParam:LPARAM
   LOCAL startInfo:STARTUPINFO
   .IF uMsg==WM_DESTROY
       invoke PostQuitMessage,NULL
   .ELSEIF uMsg==WM_INITMENUPOPUP
       invoke GetExitCodeProcess,processInfo.hProcess,ADDR ExitCode
       .if eax==TRUE
           .if ExitCode==STILL_ACTIVE
               invoke EnableMenuItem,hMenu,IDM_CREATE_PROCESS,MF_GRAYED
               invoke EnableMenuItem,hMenu,IDM_TERMINATE,MF_ENABLED
           .else
               invoke EnableMenuItem,hMenu,IDM_CREATE_PROCESS,MF_ENABLED
               invoke EnableMenuItem,hMenu,IDM_TERMINATE,MF_GRAYED
           .endif
       .else
           invoke EnableMenuItem,hMenu,IDM_CREATE_PROCESS,MF_ENABLED
           invoke EnableMenuItem,hMenu,IDM_TERMINATE,MF_GRAYED
       .endif
   .ELSEIF uMsg==WM_COMMAND
       mov eax,wParam
       .if lParam==0
           .if ax==IDM_CREATE_PROCESS
               .if processInfo.hProcess!=0
                   invoke CloseHandle,processInfo.hProcess
                   mov processInfo.hProcess,0
               .endif
               invoke GetStartupInfo,ADDR startInfo
               invoke CreateProcess,ADDR programname,NULL,NULL,NULL,FALSE,\
                                       NORMAL_PRIORITY_CLASS,\
                                       NULL,NULL,ADDR startInfo,ADDR process
Info
               invoke CloseHandle,processInfo.hThread
           .elseif ax==IDM_TERMINATE
               invoke GetExitCodeProcess,processInfo.hProcess,ADDR ExitCode
               .if ExitCode==STILL_ACTIVE
                   invoke TerminateProcess,processInfo.hProcess,0
               .endif
               invoke CloseHandle,processInfo.hProcess
               mov processInfo.hProcess,0
           .else
               invoke DestroyWindow,hWnd
           .endif
       .endif
   .ELSE
       invoke DefWindowProc,hWnd,uMsg,wParam,lParam
       ret
   .ENDIF
   xor    eax,eax
   ret
WndProc endp
end start
分析：
应用程序创建主窗口，保存菜单句柄以备后用。当用户在主菜单中选择了“Process”菜
单项后，消息处理过程中接收到WM_INITMENUPOPUP消息，我们在此处修改弹出式菜单中
的菜单项的“使能”和“非使能”，以便同一菜单有不同的显示。
   .ELSEIF uMsg==WM_INITMENUPOPUP
       invoke GetExitCodeProcess,processInfo.hProcess,ADDR ExitCode
       .if eax==TRUE
           .if ExitCode==STILL_ACTIVE
               invoke EnableMenuItem,hMenu,IDM_CREATE_PROCESS,MF_GRAYED
               invoke EnableMenuItem,hMenu,IDM_TERMINATE,MF_ENABLED
           .else
               invoke EnableMenuItem,hMenu,IDM_CREATE_PROCESS,MF_ENABLED
               invoke EnableMenuItem,hMenu,IDM_TERMINATE,MF_GRAYED
           .endif
       .else
           invoke EnableMenuItem,hMenu,IDM_CREATE_PROCESS,MF_ENABLED
           invoke EnableMenuItem,hMenu,IDM_TERMINATE,MF_GRAYED
       .endif
我们之所以处理该消息的目的就是让菜单显示时有不同的外观以方便用户的使用。譬如
；新进程尚未运行时，我们就变亮（使能）“菜单项“start process”，而变灰（非使
能）菜单项“terminate process”。当新进程运行起来后，菜单的外观就应该是相反的
。
首先我们调用GetExitCodeProcess函数，其中传入由CreateProcess返回的句柄。如果G
etExitCodeProcess返回FALSE，则表示进程尚未运行，我们就让菜单项“terminate pr
ocess”变灰；如果返回TRUE，表示新进程已经启动了，我们再检测是否正在运行，这通
过比较ExitCode是否等于STILL_ACTIVE 来完成，如果相等，表示进程仍在运行，我们就
让菜单项“start process”变灰，因为在我们的简单的应用程序中不提供同时运行多个
进程的能力。
           .if ax==IDM_CREATE_PROCESS
               .if processInfo.hProcess!=0
                   invoke CloseHandle,processInfo.hProcess
                   mov processInfo.hProcess,0
               .endif
               invoke GetStartupInfo,ADDR startInfo
               invoke CreateProcess,ADDR programname,NULL,NULL,NULL,FALSE,\
                                       NORMAL_PRIORITY_CLASS,\
                                       NULL,NULL,ADDR startInfo,ADDR process
Info
               invoke CloseHandle,processInfo.hThread
当用户选择了菜单项“start process”时，我们先检测结构体PROCESS_INFORMATION中
的成员变量hPRocess是否已经关闭。如果是第一次启动应用程序，那该变量为0，因为我
们在.data分段定义结构体时已经初始化该值为0。如果该值不为0，则表明新进程已经结
束，但是我们尚未关闭该进程的句柄（以减少该进程的引用记数），我们在此处完成该
动作。
我们调用GetStartupInfo函数来填充启动信息的结构体变量，而该变量将被传递到Crea
teProcess函数中去。调用CreateProcess生成新进程，我们不检查该函数的返回值为的
是让问题简化一些，在实际应用中，必须做该项工作。在调用CreateProcess后，我们立
即关闭在进程信息结构体参数中返回的主线程句柄，关闭线程句柄为的是减少该内核对
象的引用记数，否则即使该线程退出后，其内核对象仍惨存在内核中得不到释放，这会
引起资源泄露。进程其实也是一样，之所以我们不在该处关闭进程的句柄是因为稍后我
们还要用该句柄去得到一些和进程相关的信息，至于线程，我们的应用程序不需要其相
关信息。
           .elseif ax==IDM_TERMINATE
               invoke GetExitCodeProcess,processInfo.hProcess,ADDR ExitCode
               .if ExitCode==STILL_ACTIVE
                   invoke TerminateProcess,processInfo.hProcess,0
               .endif
               invoke CloseHandle,processInfo.hProcess
               mov processInfo.hProcess,0
当用户选择了菜单项“terminate process”后，我们调用函数GetExitCodeProcess来检
查新进程是否还存在，如果还存在我们就调用函数TerminateProcess来结束它。另外我
们把它的句柄关闭掉，因为我们再也不用它了。

--
Take it slow,     Set it couse,     Make it happen.

※ 来源:·哈工大紫丁香 bbs.hit.edu.cn·[FROM: 202.97.235.21]

Programming 版 (精华区)